Windows: Saiba como transferir uma licença de um PC para outro
Tem um computador com o sistema operativo licenciado e pretende passar essa licença para uma nova máquina? Tal procedimento é possível, no entanto, não existe uma maneira “amigável” de o fazer.
Para o ajudar, preparamos um pequeno tutorial que ensina passo-a-passo o que tem de fazer.
Para transferir uma licença do Windows de um PC para outro basicamente o que temos de fazer é desativá-la no PC antigo e ativá-la na nova máquina. Uma vez que no Windows não encontramos nenhuma ferramenta com interface gráfico para o fazer, é necessário recorrer à linha de comandos.
Para tal, devem começar por abrir o terminal de comandos em modo Administrador na máquina antiga. Não se esqueçam de guardar a chave do vosso Windows. Para obterem a chave do vosso Windows, dever aceder a este pequeno script, gravar com extensão .vbs e executar.
Option Explicit
Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductData = ProductName & vbNewLine & ProductID & vbNewLine & ProductKey
'Show messbox if save to a file
If vbYes = MsgBox(ProductData & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
Save ProductData
End If
'Convert binary to chars
Function ConvertToKey(Key)
Const KeyOffset = 52
Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
'Check if OS is Windows 8
isWin8 = (Key(66) \ 6) And 1
Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
i = 24
Maps = "BCDFGHJKMPQRTVWXY2346789"
Do
Current= 0
j = 14
Do
Current = Current* 256
Current = Key(j + KeyOffset) + Current
Key(j + KeyOffset) = (Current \ 24)
Current=Current Mod 24
j = j -1
Loop While j >= 0
i = i -1
KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
Last = Current
Loop While i >= 0
If (isWin8 = 1) Then
keypart1 = Mid(KeyOutput, 2, Last)
insert = "N"
KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
If Last = 0 Then KeyOutput = insert & KeyOutput
End If
ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
End Function
'Save data to a file
Function Save(Data)
Dim fso, fName, txt,objshell,UserName
Set objshell = CreateObject("wscript.shell")
'Get current user name
UserName = objshell.ExpandEnvironmentStrings("%UserName%")
'Create a text file on desktop
fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
Set fso = CreateObject("Scripting.FileSystemObject")
Set txt = fso.CreateTextFile(fName)
txt.Writeline Data
txt.Close
End Function
Em seguida executem o comando apresentado a seguir para procederem à desativação do vosso Windows.
slmgr.vbs /upkCaso pretendam vender ou dar a máquina, é importante que removam também a informação esta informação ao nível do registo do Windows. Tal pode ser realizado usando o comando seguinte:
slmgr.vbs /cpkyComo ativar o novo PC
Para ativar o novo PC, abram o terminal com privilégios de administrador e executem o seguinte comando:
slmgr.vbs /ipk #####-#####-#####-#####-#####E está feito! Apesar de não existir uma interface gráfica para realizar tais procedimentos, o utilizador pode seguir estes passos o proceder rapidamente à migração da licença do Windows entre PCs.
Fonte: pplware.sapo.pt
